Accendere PC da remoto senza Wake-on-LAN

Accendere il PC da remoto senza l’utilizzo del protocollo Wake-on-LAN è possibile utilizzando la scheda ESP8266, il suo modulo relè e l’assistente vocale Alexa. Una soluzione molto semplice ed economica che ti consentirà di accendere il tuo PC fisso quando sei lontano da casa.

Ma perché?
Nasce dalla necessità di accendere il pc fisso collegato nella rete domestica da una scheda usb wifi e non tramite cavo ethernet. Con questa configurazione non si può utilizzare il Wake-on-Lan, perché usa un segnale elettrico inviato tramite il cavo alla scheda di rete del pc. La soluzione proposta emula la pressione del pulsante di accensione.
Una volta acceso il computer potrai usare le varie modalità di collegamento: RDP, Teamviewer, Anydesk, VNC per poterlo utilizzare.

Introduzione alla scheda Wemos D1 Lite ESP8266 e al suo modulo relè

La scheda Wemos D1 Lite ESP8266 è una scheda di sviluppo basata sul modulo ESP8266, che offre funzionalità di connettività Wi-Fi. Il modulo relè, d’altra parte, è un componente che può essere utilizzato per controllare l’accensione e lo spegnimento di dispositivi elettrici come lampade o motori.

Il grande vantaggio del Wemos ESP8266 è che si possono collegare i suoi moduli (detti anche shield) impilandoli,
questo non richiede altre saldature se non quelle dei pin e degli zoccoli. Attenzione solo al verso dei pin.

Se non avete già la scheda, potete comprala su Amazon a questo indirizzo: https://amzn.to/3QWIZHK mentre il modulo relè a quest’altro: https://amzn.to/3QYeRMi
Comprando su AliExpress, si spende meno ma l’attesa di solito è maggiore:
https://s.click.aliexpress.com/e/_DdQJi5d e modulo relè https://s.click.aliexpress.com/e/_DeMTvvp
(I link sopra sono affiliati, a voi comprare non costa nulla di più e supportate così anche il mio lavoro).

Preparazione dell’ambiente di sviluppo

Prima di iniziare a lavorare con la scheda Wemos D1 Lite ESP8266 e il modulo relè, sarà necessario preparare l’ambiente di sviluppo. In questo articolo vedrai come installare l’IDE di Arduino su PC e configurarlo per lavorare con la scheda ESP8266.

Programmazione della scheda Wemos D1 Lite ESP8266 con relè

Devi creare un nuovo sketch, includere le librerie necessarie e incollare il codice qui sotto per controllare il modulo relè. Occorre definire solamente la tua rete Wifi con la relativa password, compilare il codice e fare il flash della memoria.

/* 
  
Accendere PC da remoto senza Wake-on-LAN

 
  Accendere il PC da remoto senza Wake-on-LAN
  
  https://www.youtube.com/@Lutritech
  https://www.facebook.com/lutritech.it/
  https://www.instagram.com/Lutritech/
  https://twitter.com/lutritech/

*/
#include <ESP8266WiFi.h>
#include <Espalexa.h>

// inserisci qui le tue credenziali del WiFi
#define STASSID "nome tua rete"
#define STAPSK "password tua rete"

const int relayPin = D1;   //lo shield relay del wemos utilizza sempre questo pin

//callback functions
void firstLightChanged(uint8_t brightness);

const char* ssid = STASSID;
const char* pass = STAPSK;

// device name
String Device_1_Name = "computer";  // è il nome del dispositivo che verrà utilizzato con Alexa
Espalexa espalexa;

void setup() {
  Serial.begin(115200);

  pinMode(relayPin, OUTPUT);

  // We start by connecting to a WiFi network
  Serial.print("Connecting to ");
  Serial.println(ssid);
  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, pass);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");

  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());

  // Define your devices here.
  espalexa.addDevice(Device_1_Name, firstLightChanged);  //simplest definition, default state off
  espalexa.begin();
  digitalWrite(relayPin, LOW); //all'accensione il contatto è aperto
}

void loop() {
  espalexa.loop();
  delay(500);
}

//our callback functions
void firstLightChanged(uint8_t brightness) {
  //Control the device
  if (brightness) {
    Serial.println(brightness);
    if (brightness == 255) {
      Serial.println("Accendo il pc");
      digitalWrite(relayPin, HIGH);
      delay(1000); //come se tenessi premuto il pulsante per un secondo
      digitalWrite(relayPin, LOW);
    }

  } else {
    Serial.println(brightness);
    Serial.println("Spengo il pc");
    digitalWrite(relayPin, HIGH);
    delay(5000); //come se tenessi premuto il pulsante per 5 secondi
    digitalWrite(relayPin, LOW);
  }
}

Apriamo il nostro PC

Ti consiglio di consultare il manuale della scheda madre o del tuo PC. Se non dovessi averli cerca su google.it inserendo manuale modello marca, per esempio nel mio caso ho cercato “manual Asus H110M-R”. Nel manuale in pdf ricerca la parte inerente al Panel Connector o a qualcosa del genere.

Nel mio caso, in giallo trovate quali sono i 2 pin che se cortocircuitati fanno accendere il computer.

Fai bene attenzione: spegni completamente il pc.
Stacca il cavo di alimentazione e spegni la ciabatta elettrica a cui è collegato. Solo dopo apri il tuo case e individua la zona interessata: avrai già ai due pin collegati due cavetti che andranno al pulsante di accensione posto sulla parte anteriore del tuo case. Scollegali dalla scheda madre e collega il modulo relè come mostrato qui sotto usando 2 cavetti maschio-femmina.

Nota bene: in tutte le schede madri “manca” un pin nella prima riga a destra, per riconoscere i pin dell’accensione.

Collegando il modulo relè al pulsante di accensione del PC possiamo simulare quindi la pressione del pulsante per accenderlo. Il vantaggio di questa soluzione rispetto ad una presa domotica è che si può usare l’alimentazione USB della stessa scheda madre per alimentare direttamente la scheda wemos, basta cercare nel Bios nella voce Advanced.

Se preferisci puoi portare fuori dal case il ESP8266 e Relè usando un alimentatore usb, ma dovrai utilizzare dei cavi più lunghi che vadano poi alla scheda madre.

In ogni caso, ora chiedi ad Alexa di cercare nuovi dispositivi, troverà un nuovo dispositivo chiamato “computer”, perché nel codice è stato descritto in questo modo. Basterà chiedere ad Alexa di “accendere il computer” e il pc si avvierà! Ricordati di riattaccare il cavo di alimentazione e di accendere la ciabatta elettrica 🙂

Puoi decidere anche di tenere il pulsante di accensione originale utilizzando lo schema sotto.
In pratica avremo 2 pulsanti in parallelo.

Ho comprato un pulsante esterno RGB con 2metri di cavo e uno splitter da Aliexpress: costo 2.5 euro,
in caso lo consiglio.

Lo splitter ci consente in questo caso di poter collegare sia il pulsante(filo bianco e verde) che la scheda wemos con il suo relè (fili gialli). Posizionate poi questo ultimo con una fascetta stando attenti a non far toccare i pin metallici al case metallico. Ho stampato un piccolo case per contenere la scheda per maggior sicurezza:

Conclusioni

Utilizzando la scheda Wemos D1 Lite ESP8266 e il suo modulo relè avremo l’accensione remota della nostra postazione PC senza usare Wake-on-LAN. Sperimenta questa soluzione e godi della comodità di accendere PC da remoto in modo sicuro ed efficiente con i comandi vocali di Alexa.